Das Kefk Network Wiki befindet sich im Testbetrieb.

Integralsinus

Aus Kefk.

Wechseln zu: Navigation, Suche

Der Integralsinus ist ein Begriff aus der Mathematik und bezeichnet eine durch ein Integral gegebene Funktion.

Joseph Liouville (1809-1882) bewies, dass der Kardinalsinus nicht elementar integrierbar ist.

Der Integralsinus ist definiert als das Integral der Sinc-Funktion:

\mathrm{Si}\left(x\right):=\int_0^x \mathrm{sinc}\left(t\right)\, \mathrm{d}t=\int_0^x \frac{\sin\left(t\right)}{t}\, \mathrm{d}t. [1]

Im Grenzübergang \lim_{x\to \infty} \mathrm{Si}\left(x\right) kann das Integral ausgewertet werden. Es gilt:

\lim_{x\to \infty} \mathrm{Si}\left(x\right)=\frac{\pi}{2}

Die Entwicklung in eine Taylorreihe an der Stelle 0 liefert die gleichmäßig konvergente Reihe:

\mathrm{Si}\left(x\right)=x-\frac{x^3}{3!\cdot3}+\frac{x^5}{5!\cdot5}-\frac{x^7}{7! \cdot7}+\cdots=\sum_{k=0}^\infty \frac{(-1)^{k}}{(2k+1)!\cdot(2k+1)}x^{2k+1}

Algorithmus

Diese Reihe lässt sich ziemlich leicht programmieren: 

Const Epsilon=1E-10; {oder ein andere Genauigkeit}
Function Si(x:Extended):Extended;
 Function xHochN(x:Extended;n:Byte):Extended;
 Var y:Extended;
     i:Byte;
 Begin
  y:=1;
  For i:=1 To n Do y:=y*x;
  xHochN:=y
 End;
 Function Fakultaet(n:Word):Extended;
 Var f:Extended;
     i:Word;
 Begin
  f:=1;
  For i:=1 To n Do f:=f*i;
  Fakultaet:=f
 End;
Var ISinus,Delta:Extended;
    n           :Word;
Begin
 n:=0;ISinus:=0;
 Repeat
  Delta:=xHochN(-1,n)*xHochN(x,2*n+1)/((2*n+1)*Fakultaet(2*n+1));
  ISinus:=ISinus+Delta;Inc(n)
 Until Abs(Delta)<Epsilon;
 Si:=ISinus
End;

Diese Version ist jedoch langsam, da bei jedem Durchgang xHochN und die Fakultät neu berechnet werden müssen.

Eine schnellere Variante ergibt folgende Pascal-Funktion: 

Function Si(x:Extended):Extended;
Var ISinus,Fakultaet,Potenz,Delta:Extended;
    n                            :Word;
    Vorzeichen                   :-1..1;
Begin
 ISinus:=x;n:=1;Fakultaet:=1;Potenz:=x;x:=Sqr(x);Vorzeichen:=-1;
 Repeat
  Potenz:=Potenz*x;Fakultaet:=Fakultaet*(n+1)*(n+2);Inc(n,2);
  Delta:=Potenz/(n*Fakultaet);
  ISinus:=ISinus+Vorzeichen*Delta;Vorzeichen:=-Vorzeichen
 Until Abs(Delta)<Epsilon;
 Si:=ISinus
End;

Siehe auch

Quellen

  1. ↑ Handbuch der Mathematik, Seite 517 ISBN 3-8166-0015-9
Von „http://kefk.org/wiki/Integralsinus“
Persönliche Werkzeuge
Andere Sprachen